init

.gitignore

@@ -0,0 +1,4 @@
+cimgui/
+pkg/
+src/
+*.zst

Makefile.patch

@@ -0,0 +1,19 @@
+diff --git a/Makefile b/Makefile
+index d5462fc..92a5330 100644
+--- a/Makefile
++++ b/Makefile
+@@ -8,8 +8,13 @@ OBJS += ./imgui/imgui_draw.o
+ OBJS += ./imgui/imgui_demo.o
+ OBJS += ./imgui/imgui_tables.o
+ OBJS += ./imgui/imgui_widgets.o
++OBJS += ./imgui/backends/imgui_impl_vulkan.o
++OBJS += ./imgui/backends/imgui_impl_glfw.o
++OBJS += ./imgui/backends/imgui_impl_glut.o
++OBJS += ./imgui/backends/imgui_impl_opengl2.o
++OBJS += ./imgui/backends/imgui_impl_opengl3.o
+ 
+-CXXFLAGS=-O2 -fno-exceptions -fno-rtti
++CXXFLAGS=-O3 -fno-exceptions -fno-rtti -DIMGUI_IMPL_API='extern "C"' -DIMGUI_IMPL_OPENGL_LOADER_GLEW
+ 
+ UNAME_S := $(shell uname -s)
+ 

PKGBUILD

@@ -0,0 +1,48 @@
+# Maintainer: LordMZTE <lord at mzte dot de>
+
+_pkgname=cimgui
+pkgname=${_pkgname}-git
+pkgver=r796.9ce2c32
+pkgrel=1
+pkgdesc="C bindings for Dear ImGui"
+license=('MIT')
+arch=('x86_64')
+url="https://github.com/cimgui/cimgui"
+depends=('gcc-libs')
+makedepends=('vulkan-headers' 'glfw' 'make')
+provides=('cimgui')
+conflicts=('cimgui')
+source=("git+https://github.com/cimgui/cimgui.git" "Makefile.patch" "cimgui.pc")
+sha256sums=('SKIP'
+            'c336a19e14816ae89c3b3248a2756739ec5be757878e091aec7bb468b0454b9d'
+            '1b0737f9d9ae73344768273a86aed616473b1b761f321695c893e58e418c4ad3')
+
+
+pkgver() {
+    cd "$_pkgname"
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+    cd "$_pkgname"
+    git submodule update --init
+    patch --forward --strip=1 --input="${srcdir}/Makefile.patch"
+}
+
+build() {
+    cd "$_pkgname"
+    make
+}
+
+package() {
+    install -D -m644 cimgui.pc "${pkgdir}/usr/lib/pkgconfig/cimgui.pc"
+
+    cd "$_pkgname"
+
+    install -D -m644 README.md "${pkgdir}/usr/share/doc/${_pkgname}/README.md"
+    install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
+
+    install -D -m777 cimgui.so "${pkgdir}/usr/lib/libcimgui.so"
+    install -D -m644 cimgui.h "${pkgdir}/usr/include/cimgui.h"
+    install -D -m644 generator/output/cimgui_impl.h "${pkgdir}/usr/include/cimgui_impl.h"
+}

cimgui.pc

@@ -0,0 +1,10 @@
+prefix=/usr
+libdir=${prefix}/lib
+includedir=${prefix}/include
+
+Name: cimgui
+Description: C bindings for Dear ImGui
+Version:
+Requires:
+Libs: -L${libdir} -lcimgui
+Cflags: -I${includedir}