This commit is contained in:
LordMZTE 2022-08-14 15:10:27 +02:00
commit 0c9714a2cd
Signed by: LordMZTE
GPG Key ID: B64802DC33A64FF6
3 changed files with 51 additions and 0 deletions

38
PKGBUILD Normal file
View File

@ -0,0 +1,38 @@
# Maintainer: Myrddin Wyllt <darknesseatsall at aim dot com>
pkgname=openrgb-git
pkgver=r2571.859f15a5
pkgrel=1
pkgdesc="Configuration utility for RGB lights supporting motherboards, RAM, & peripherals"
arch=('x86_64')
url="https://gitlab.com/CalcProgrammer1/OpenRGB"
license=('GPL2')
depends=('qt5-base' 'libusb' 'hidapi' 'mbedtls')
makedepends=('git')
optdepends=('i2c-tools: Motherboard & RAM access')
provides=('openrgb')
conflicts=('openrgb')
source=("git+https://gitlab.com/CalcProgrammer1/OpenRGB.git"
openrgb.conf
openrgb.service)
sha256sums=('SKIP'
'b5a53d747422f8b594e3e9615e238457d696732efce94050cdd72182a8645ef2'
'272dc43a77d0e48d29f32da753c7e05fd635883b173c21047f4eefa8bfc77938')
pkgver() {
cd OpenRGB
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "$srcdir/OpenRGB"
qmake OpenRGB.pro
make
}
package() {
install -Dm644 -t "$pkgdir"/usr/lib/modules-load.d "."/openrgb.conf
install -Dm644 -t "$pkgdir"/usr/lib/systemd/system "."/openrgb.service
cd OpenRGB
make INSTALL_ROOT="$pkgdir" install
}

1
openrgb.conf Normal file
View File

@ -0,0 +1 @@
i2c-dev

12
openrgb.service Normal file
View File

@ -0,0 +1,12 @@
[Unit]
Description=Run openrgb server
After=network.target lm_sensors.service
[Service]
RemainAfterExit=yes
ExecStart=/usr/bin/openrgb --server
Restart=always
[Install]
WantedBy=multi-user.target